VB初心者友の会 - はじめたばかりの人専用Q&A掲示板過去ログ

> 「ファイル名」：「サイズ」：「更新日時」：「各ファイルの一行目の内容表示」を
> 表示できる、FileListBoxを作成したいのですが、プロパティ、もしくはコ−ド表示
> はどのようにすればよいのですか？教えてください。

エクスプローラーの右側みたいなヤツですね。
コントロールとしては、リストビューを使います。
情報は、自前で取るしかありません。(^^;
＃Dir でループしてファイル取得、FileSize・FileDateTime でサイズと更新日時、
　１行目は、Open/Line Input/Close。

> > 「ファイル名」：「サイズ」：「更新日時」：「各ファイルの一行目の内容表示」を
> > 表示できる、FileListBoxを作成したいのですが、プロパティ、もしくはコ−ド表示
> > はどのようにすればよいのですか？教えてください。
> 
> エクスプローラーの右側みたいなヤツですね。
> コントロールとしては、リストビューを使います。
> 情報は、自前で取るしかありません。(^^;
> ＃Dir でループしてファイル取得、FileSize・FileDateTime でサイズと更新日時、
> 　１行目は、Open/Line Input/Close。

ありがとうございます。
参考図書をもとに”Listvew”を作成しましたが、ファイル名の取得までできました
しかし、「フォルダ−内の各ファイルの一行目表示」
　　　　「ファイルサイズの取得　　FileSize」
　　　　「更新日の取得」３項目が表示できません。
以下にコ−ドを書いています。
どの様に手直しすべきでしょうか？
悩める初心者です。

Private Sub Dir1_Change()
    ChDir Dir1.Path
    ListView1.ListItems.Clear
    p = Dir("*.*", 2 + 4 + 16)
    Do While p <> ""
        If Not (p = "." Or p = ".") Then
            Set lv = ListView1.ListItems.Add(, , p)                    'ファイル名の取得
            'set lv = subitems(1) = Open/Line Input/Close　　　　　　　’フォルダ−内の各ファイルの一行目表示
            'Set lv.SubItems(2) = (FileLen(p) + 1023) \ 1024 & "KB"　　’ファイルサイズの取得　　FileSize
　          'Set lv.SubItems(3) = FileDateTime(p)　　　　　　　　　　　’更新日の取得
        End If
        p = Dir
    Loop
            
End Sub

Private Sub Drive1_Change()
    ChDrive Drive1.Drive
    Dir1.Path = Drive1.Drive
    Dir1_Change
End Sub

Private Sub Form_Load()
    Dim x As ColumnHeader
    w = ListView1.Width / 3.5
    Set x = ListView1.ColumnHeaders.Add(, , "ファイル名", ListView1.Width / 5)
    Set x = ListView1.ColumnHeaders.Add(, , "情報", ListView1.Width / 2, 1)
    Set x = ListView1.ColumnHeaders.Add(, , "サイズ", ListView1.Width / 5, 1)
    Set x = ListView1.ColumnHeaders.Add(, , "更新日時", ListView1.Width / 4, 1)
    
    ListView1.View = lvwReport
    Dir1_Change
    
End Sub

SubItem は文字列です。Set はいりません。(^^;

            Set lv = ListView1.ListItems.Add(, , p)
            lv.SubItems(1) = File_FirstLine(p)
            lv.SubItems(2) = (FileLen(p) + 1023) \ 1024 & "KB"
            lv.SubItems(3) = FileDateTime(p)

Public Function File_FirstLine(ByVal FullName As String) As String
    Dim h As Long
    On Error GoTo ErrHandle

    If GetAttr(FullName) = vbDirectory Then
        File_FirstLine = "<Dir>"
    Else
        h = FreeFile
        Open FullName For Input Access Read Lock Write As h
        Line Input #h, File_FirstLine
        Close #h
    End If
    Exit Function
    
ErrHandle:
    File_FirstLine = ""
    Exit Function
End Function

ありがとうございました。うまくいきました。

ちなみに、2行目、3行目、最終行を取得するには？

Public Function File_FirstLine(ByVal FullName As String) As String
    Dim h As Long
    On Error GoTo ErrHandle

    If GetAttr(FullName) = vbDirectory Then
        File_FirstLine = "<Dir>"
    Else
        h = FreeFile
        Open FullName For Input Access Read Lock Write As h
        Line Input #h, File_FirstLine
        Close #h
    End If
    Exit Function
    
ErrHandle:
    File_FirstLine = ""
    Exit Function
End Function

File_FirstLineをどの様に記述すればよろしいでしょうか？
2行目・・・・　　　
3行目・・・・
最終行・・・

悩める初心者

ありがとうございました。うまくいきました。

ちなみに、2行目、3行目、最終行を取得するには？

Public Function File_FirstLine(ByVal FullName As String) As String
    Dim h As Long
    On Error GoTo ErrHandle

    If GetAttr(FullName) = vbDirectory Then
        File_FirstLine = "<Dir>"
    Else
        h = FreeFile
        Open FullName For Input Access Read Lock Write As h
        Line Input #h, File_FirstLine
        Close #h
    End If
    Exit Function
    
ErrHandle:
    File_FirstLine = ""
    Exit Function
End Function

File_FirstLineをどの様に記述すればよろしいでしょうか？
2行目・・・・　　　
3行目・・・・
最終行・・・

悩める初心者

普通の方法であれば、ループして各行を取得し、そのとき行数を数えてください。
1 行目、2 行目は、その行数で分岐して取得します。
最後の行は、ループから出たときの、Line Input に使った変数になります。

         iRec = 1
         h = FreeFile
         Open FullName For Input Access Read Lock Write As h
         Do Until EOF(h)
             Line Input #h, sLine
             Select Case iRec
                 Case 1: ...
                 Case 2: ...
             End Select
             iRec = iRec + 1
         Loop
         Close #h
 
ファイル全体を取得して、それを Split で分解する方もあります。
速度的にはコッチの方が速いですが、すべてのファイルを開いてたらやっぱり遅いでしょう。(^^;
Public Function TextFile_ReadAll(ByVal FullName As String) As String
    Dim h As Long
    Dim sWhole As String

    h = FreeFile
    Open FullName For Input Access Read Lock Write As h
    File_GetWhole = StrConv(InputB$(LOF(h), h), vbUnicode)
    Close #h
End Function

Public Sub Test()
    Dim asLines As Variant
    
    asLines = Split(TextFile_ReadAll("c:\test.txt"), vbCRLF)
    Debug.Print asLines(0)
    Debug.Print asLines(1)
    Debug.Print asLines(UBound(asLines))
End Sub

> 普通の方法であれば、ループして各行を取得し、そのとき行数を数えてください。
> 1 行目、2 行目は、その行数で分岐して取得します。
> 最後の行は、ループから出たときの、Line Input に使った変数になります。
> 
>          iRec = 1
>          h = FreeFile
>          Open FullName For Input Access Read Lock Write As h
>          Do Until EOF(h)
>              Line Input #h, sLine
>              Select Case iRec
>                  Case 1: ...
>                  Case 2: ...
>              End Select
>              iRec = iRec + 1
>          Loop
>          Close #h
>  

大変お世話になりました。
おかげさまでうまくいきました。
このファイルコントロ−ルシステムを使って次のチャレンジをしたいと思います。
また、質問が出てくると思いますので、その節はよろしくお願いします。・・・　　\　〇　〇　／　バンザイ

悩み解消