VB初心者友の会 - はじめたばかりの人専用Q&A掲示板過去ログ

> VBで４桁の乱数を発生させたいのです。
> 聞くところによると、rand関数はなぜかランダムではない
> という話を聞きました。（その理由も知っている方がいらっしゃいましたら
> 教えてください）

Randomize を使えば OK

> そもそも、VBに関数があるのでしょうか？

n = Int(Rnd * 9000) + 1000

ランダムでない理由は知りませんが、Randomizeを使えばバラバラになりますよ

４桁のランダム値は
ret = Int(Rnd * 9000) + 1000
でよろしいかと…

> VBで４桁の乱数を発生させたいのです。

こんな感じでどうでしょう。

Private Sub Form_Load()
    Dim i As Long
    Dim result(100) As Long
    Dim L As Long
    
    Randomize
    
    For i = 0 To 1000000
        L = Int(Rnd * 9000) + 1000
        result(L \ 100) = result(L \ 100) + 1
    Next
    
    ' 例：reault(10)は1000〜1999の値の数です。
    For i = 10 To 99
        Debug.Print result(i)
    Next
End Sub

乱数の分布のチェック付きです。

> 聞くところによると、rand関数はなぜかランダムではない

Rnd関数ですね。

> という話を聞きました。（その理由も知っている方がいらっしゃいましたら
> 教えてください）

どういう観点でランダムではないという意見があるのかがわからないので
なんとも言えません。

Rnd関数はそれなりに真っ当な乱数を生成していると思いますが。

ただし、Rnd関数をベースに計算した値を使用するので、
計算式によっては、乱数が片寄る場合はあります。

残念ながら、完全に不規則な数列を「計算で」求めることはできません。
VBに限らず、乱数関数によって作られる「乱数」は、実は循環周期のきわめて長い
循環数列です、いわゆる擬似乱数です。
乱数を作るアルゴリズムでしたら、線形合同法あたりが有名です。

せっかくですから、VBの乱数が規則的であるところを視覚的にお見せしましょう。

Formにボタン2つおいてください。
下記コードをコピーして実行します。
Command1をおしたら、点をばらまきますが、
Command2をおせば、あーらふしぎ・・・(やってのお楽しみ)
rndは15桁の擬似乱数を作りますが、下位の桁ほど循環間隔が小さくなります。

Private Sub Command1_Click()
    Dim lngX As Long
    Dim lngY As Long
    Dim i As Long

    For i = 1 To 10000
        lngX = Int(Rnd * 4096)
        lngY = Int(Rnd * 4096)
        Form1.PSet (lngX, lngY), RGB(255, 255, 255)
    Next
End Sub

Private Sub Command2_Click()
    Dim lngX As Long
    Dim lngY As Long
    Dim strX As String
    Dim strY As String
    Dim i As Long

    For i = 1 To 10000
        strX = Format(Rnd * 1E+15, "000000000000000")
        strY = Format(Rnd * 1E+15, "000000000000000")
        strX = Right(strX, 4)
        strY = Right(strY, 4)
        lngX = CLng(strX)
        lngY = CLng(strY)
        Form1.PSet (lngX, lngY), RGB(255, 255, 255)
    Next

End Sub

Private Sub Form_Load()
    Form1.BackColor = RGB(0, 0, 0)
'
End Sub